1i\
'\\" t\
\.\\"\
\.\\" Modified for Solaris to to add the Solaris stability classification,\
\.\\" and to add a note about source availability.\
\.\\"\ 
# User Commands (section)
s/.TH VIM 1/.TH GVIM 1/
s/.TH VIMDIFF 1/.TH GVIMDIFF 1/
# Name
s/^vim \\- Vi IMproved/gvim \\- Vi IMproved/
s/^vimdiff \\- edit two or three versions of a file with Vim/gvimdiff \\- edit two or three versions of a file with GVim/
# Synopsis (note extra space at the end)
s/^.B vim$/.B gvim /
s/^.B vimdiff$/.B gvimdiff /
# Synopsis - continuning (list of other commands)
/^.B ex$/,/^.br$/ d
/^.B view$/,/^.br$/d
/^.B gvim$/ d
/^.B evim$/ d
/^.B eview$/,/^.br$/ d
/^.B rvim$/ d
/^.B rview$/ d
/^.B gvimdiff$/ d
# Description
s/^.B Vim/.B GVim/
s/^is a text editor/is the GUI version of the vim(1) text editor/
s/vim file$/gvim file/
s/vim \[options\] \[filelist\]$/gvim [options] [filelist]/
s/See vim(1) for details about Vim itself./See gvim(1) for details about GVim itself./
s/For all other arguments see vim(1)./For all other arguments see gvim(1)./
# File refrence
s/^\/usr\/local\/lib\/vim/\/usr\/share\/vim\/vim72/
# References to other man pages
s/^vim(1)$/gvim(1)/
s/^vimtutor(1)$/vimtutor(1) vim(1)/
# Stability classification and source availability
$a\
\.\\" Begin Sun update\
.SH ATTRIBUTES\
See\
.BR attributes (5)\
for descriptions of the following attributes:\
.sp\
.TS\
box;\
cbp-1 | cbp-1\
l | l .\
ATTRIBUTE TYPE	ATTRIBUTE VALUE\
=\
Availability	editor/gvim\
=\
Interface Stability	Uncommitted\
.TE \
.PP\
.SH NOTES\
Source for vim is available on http://opensolaris.org.\
\.\\" End Sun update