#! /usr/perl5/bin/perl -w

#
# Copyright 2008 Sun Microsystems, Inc.  All rights reserved.
# Use is subject to license terms.
#
# Permission is hereby granted, free of charge, to any person obtaining a
# copy of this software and associated documentation files (the
# "Software"), to deal in the Software without restriction, including
# without limitation the rights to use, copy, modify, merge, publish,
# distribute, and/or sell copies of the Software, and to permit persons
# to whom the Software is furnished to do so, provided that the above
# copyright notice(s) and this permission notice appear in all copies of
# the Software and that both the above copyright notice(s) and this
# permission notice appear in supporting documentation.
# 
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
# OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
# MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT
# OF THIRD PARTY RIGHTS. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR
# HOLDERS INCLUDED IN THIS NOTICE BE LIABLE FOR ANY CLAIM, OR ANY SPECIAL
# INDIRECT OR CONSEQUENTIAL DAMAGES, OR ANY DAMAGES WHATSOEVER RESULTING
# FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT,
# NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION
# WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
# 
# Except as contained in this notice, the name of a copyright holder
# shall not be used in advertising or otherwise to promote the sale, use
# or other dealings in this Software without prior written authorization
# of the copyright holder.
#
# ident "@(#)xmake 1.1     08/08/07 SMI"
#

require 5.005;				# minimal Perl version required
use strict;				#
use diagnostics;			#
use File::Spec;
use English qw( -nomatchvars );

# Path to make sure we're running Solaris make instead of GNU make
my $solaris_make = '/usr/ccs/bin/make';

# save full path to current directory
my $startdir = File::Spec->rel2abs(File::Spec->curdir());

# climb the tree to find the open-src module directory we're in
my @dirtree = File::Spec->splitdir($startdir);
my $osdepth;

for my $n (1..$#dirtree) {
  if ($dirtree[$n] eq 'open-src') {
    if (-f File::Spec->catfile( @dirtree[0..$n], 'common/Makefile.inc')) {
      $osdepth = $n;
      last;
    }
  }
}

if (!defined($osdepth)) {
  die "$0: Cannot find path to open-src/common/Makefile.inc from here";
}

# if in top two levels, just run make
if ($osdepth >= ($#dirtree - 2)) {
  print join(' ', $solaris_make, @ARGV), "\n";
  exec($solaris_make, @ARGV)
    or die "$0: exec of $solaris_make failed: $OS_ERROR";
}

my $subdir_target = 'build-in-subdir';
for my $f (@ARGV) {
  if ($f =~ m{^install}ms) {
    $subdir_target = 'install-in-subdir';
  }
}

# Otherwise get info from the module makefile
my $moduledir = File::Spec->catdir( @dirtree[0..($osdepth+2)] );

my @makeargs = ($subdir_target, qq{subdir='$startdir'});
if (scalar(@ARGV) > 0) {
  push @makeargs, join(q{}, q{subdir_cmd='}, @ARGV, q{'});
}

print join(' ', "(cd $moduledir ;\\\n", $solaris_make, @makeargs), ")\n";
chdir $moduledir
  or die "$0: Can't chdir $moduledir: $OS_ERROR";
exec($solaris_make, @makeargs)
    or die "$0: exec of $solaris_make failed: $OS_ERROR";

__END__