#!/usr/bin/perl

use strict;

use warnings;

use Getopt::Long qw(:config gnu_getopt no_auto_abbrev);

use rpm_spec;

# --------- defaults -------------------------------------------------------

my $default_spec_dir = `dirname $0`;

$default_spec_dir =~ s/\s//g;

my $default_log_dir = '/tmp';

my $default_tarball_dir = "/sgnome/pkgs/gnome-2.2/misc/tarballs";

my $default_source_dirs = $default_spec_dir . "/ext-sources" .

			":" . $default_spec_dir . "/manpages/man1" .

			":" . $default_spec_dir . "/manpages/man3" .

			":" . $default_spec_dir . "/manpages/man4" .

			":" . $default_spec_dir . "/manpages/man5";

my $default_patch_dir = $default_spec_dir . "/patches";

my $default_sys_rpm_dir = "/usr/src/packages";

my $default_nightly_date_format = '%y%m%d';

# --------- global vars ----------------------------------------------------

# config settings

my $the_spec_dir = $default_spec_dir;

my $the_log_dir = $default_log_dir;

my $the_summary_log;

my $the_summary_title;

my $the_logdir_url;

my $the_rpm_url;

my $the_srpm_url;

my $the_source_dirs = $default_source_dirs;

my @the_source_dirlist;

my $the_tarball_dir = $default_tarball_dir;

my $the_good_build_dir;

my $the_good_rpms_copy_dir;

my $the_patch_dir = $default_patch_dir;

my $the_sys_rpm_dir = $default_sys_rpm_dir;

my $rpm_target;

my $check_deps = 1;

my $live_summary = 0;

my $build_command;

my $exit_val = 0;

my $verbose = 1;

my $debug_level = 0;

my $full_path = 0;

my $halt_on_errors = 0;

my $mail_errors_file;

my $mail_errors_to;

my $mail_errors_cc;

my $prodname = "unnamed";

my $is_nightly = 0;

my $the_nightly_date_format = $default_nightly_date_format;

# counter used as an id for the spec files

my $spec_id = 0;

# array of spec objects

my @specs_to_build = ();

my @build_status;

my @status_details;

my @remove_list = ();

my %provider;

my %warned_about;

# --------- utility functions ----------------------------------------------

our $opt_specdir = $default_spec_dir;

# return the name of the log file given the id of the spec file

sub get_log_name ($) {

    my $spec_id = shift;

    my $spec = $specs_to_build[$spec_id];

    my $spec_file = $spec->get_param ('file_name');

    my $base_name = $spec_file;

    $base_name =~ s/^.*\/([^\/]+)/$1/;

    my $log_name = "$base_name";

    $log_name =~ s/(\.spec|)$/.log/;

    return $log_name;

}

my $current_log;

sub open_log ($) {

    my $log_filename = shift;

    if (not defined ($log_filename)) {

	return;

    }

    if (defined ($current_log)) {

	if ($current_log ne $log_filename) {

	    close LOG_FILE;

	}

    }

    $current_log = undef;

    if (! open LOG_FILE, ">>$log_filename") {

	msg_warning (0, "Failed to open log file $log_filename");

	return;

    }

    $current_log = $log_filename;

    msg_log ("--- log starts --- " . `date`);

}

sub close_log () {

    msg_log ("--- log ends --- " . `date`);

    close LOG_FILE;

    $current_log = undef;

}

sub print_message ($$) {

    my $min_verbose = shift;

    my $message = shift;

    chomp $message;

    if ($verbose > $min_verbose) {

	print "$message\n";

    }

    if (defined ($current_log)) {

	print LOG_FILE "$message\n";

    }

}

sub msg_error ($) {

    my $message = shift;

    print_message (0, "ERROR: $message");

    if ($halt_on_errors > 0) {

	print "ERROR: Exiting...\n";

	exit (255);

    }

}

sub msg_warning ($$) {

    my $min_verbose = shift;

    my $message = shift;

    print_message ($min_verbose, "WARNING: $message");

}

sub msg_info ($$) {

    my $min_verbose = shift;

    my $message = shift;

    print_message ($min_verbose, "INFO: $message");

}

sub msg_debug ($$) {

    my $min_debug = shift;

    my $message = shift;

    if ($debug_level > $min_debug) {

	print "DEBUG: $message\n";

    }

}

sub msg_log ($) {

    my $message = shift;

    if (defined ($current_log)) {

	print LOG_FILE "$message\n";

    }

}

sub find_file ($) {

    my $glob = shift;

    my @files = `find $glob 2>&1`;

    if ($? == 0) {

	my $file = $files[$#files];

	chomp $file;

	return ($file);

    }

    return (undef);

}

sub mail_log ($) {

    my $spec_id = shift;

    my $address;

    my $cc;

    my $log_name = get_log_name ($spec_id);

    my $spec_name = $specs_to_build[$spec_id]->{name};

    my $base_name = $log_name;

    $log_name =~ s/\.log$//;

    if (defined ($mail_errors_file)) {

	$address = get_address_from_file ($mail_errors_file, $base_name);

	if (not defined ($address)) {

	    $address = $mail_errors_to;

	} else {

	    $cc = $mail_errors_cc;

	}

    }

    my $log_file = get_log_name ($spec_id);

    msg_info (1, "mailing the build log to $address");

    if (not defined ($address)) {

	return;

    }

    my $subject;

    if (defined ($prodname)) {

	$subject = "BUILD FAILED ($prodname): $spec_name";

    } else {

	$subject = "BUILD FAILED: $spec_name";	

    }

    if (defined ($cc)) {

	`cat $the_log_dir/$log_file | mailx -s "$subject" -c "$cc" $address`;

    } else {

	`cat $the_log_dir/$log_file | mailx -s "$subject" $address`;

    }

}

sub get_address_from_file ($$) {

    my $fname = shift;

    my $pkg = shift;

    $pkg =~ s/\.spec$//;

    if (! open ADDR_FILE, "<$fname") {

        msg_warning (0, "Could not open file $fname");

	return undef;

    }

    my @lines = <ADDR_FILE>;

    my @addresses = grep /^$pkg:/, @lines;

    my $address = $addresses[0];

    if (not defined ($address)) {

	return undef;

    }

    $address =~ s/^$pkg://;

    $address =~ s/\s//g;

    close ADDR_FILE;

    return $address;

}

# --------- functions to process the command line args ---------------------

sub add_spec ($) {

    my $spec_name = shift;

    my $spec;

    if (-f $spec_name) {

	$spec = rpm_spec->new ($spec_name, $rpm_target);

    } else {

	if (not $spec_name =~ /\.spec$/) {

	    $spec_name = "${opt_specdir}/${spec_name}.spec";

	}

	$spec = rpm_spec->new ("$spec_name", $rpm_target);

    }

    if (not defined ($spec)) {

	msg_error ("$spec_name not found\n");

    } else {

	my $this_spec_id = $spec_id ++;

	$specs_to_build[$this_spec_id] = $spec;

	my @packages = $spec->get_param_array ('packages');

	$build_status[$this_spec_id] = 'NOT_BUILT';

	$status_details[$this_spec_id] = '';

	foreach my $pkg (@packages) {

	    my @provides = $spec->get_pkg_param_array ($pkg, 'provides');

	    foreach my $prov (@provides) {

		if (not defined $prov) {

		    next;

		}

		$prov =~ s/ .*//;

		$provider{$prov} = $this_spec_id;

	    }

	}

    }

}

sub set_quiet {

    $verbose = 0;

}

sub process_args {

    my $arg = shift;

    if (not defined ($build_command)) {

	if (($arg ne "build") and ($arg ne "build-order") and

	    ($arg ne "uninstall-pkgs") and

	    ($arg ne "install-order")) {

	    msg_error ("unknown command: $arg");

	    usage (1);

	}

	$build_command = $arg;

    } else {

	add_spec ($arg);

    }

}

sub process_options {

  Getopt::Long::Configure ("bundling");

    our $opt_logdir = $default_log_dir;

    our $opt_sourcedirs = $default_source_dirs;

    our $opt_tarballdir = $default_tarball_dir;

    our $opt_good_build_dir;

    our $opt_good_rpms_copy_dir;

    our $opt_patchdir = $default_patch_dir;

    our $opt_rpmdir = $default_sys_rpm_dir;

    our $opt_deps = 1;

    our $opt_live_summary = 0;

    our $opt_nightly = 0;

    our $opt_summary_log;

    our $opt_summary_title;

    our $opt_logdir_url;

    our $opt_rpm_url;

    our $opt_srpm_url;

    our $opt_date = $default_nightly_date_format;

    GetOptions ('v|verbose+' => \$verbose,

		'debug=n' => \$debug_level,

		'q|quiet' => \&set_quiet,

		'specdir|spec|S=s',

		'halt-on-errors!', \$halt_on_errors,

		'mail-errors-to=s' => \$mail_errors_to,

		'mail-errors-cc=s' => \$mail_errors_cc,

		'mail-errors-file=s' => \$mail_errors_file,

		'prodname=s' => \$prodname,

		'sourcedirs|sourcedir|src|srcdirs|srcdir|sources|source|s=s',

		'logdir|log|l=s',

		'summary-log=s',

		'live-summary|live!',

		'summary-title=s',

		'logdir-url=s',

		'rpm-url=s',

		'srpm-url=s',

		'target=s' => \$rpm_target,

		'deps!',

		'tarballdir|tar|tarball|tardir|t=s',

		'good-build-dir=s',

		'good-rpms-copy-dir=s',

		'nightly!',

		'date|date-format|nightly-date-format=s',

		'patchdir|patch|p=s',

		'rpmdir|rpm|r=s',

		'full-path' => \$full_path,

		'help' => \&usage,

		'<>' => \&process_args);

    $the_spec_dir = $opt_specdir;

    $the_log_dir = $opt_logdir;

    $the_summary_log = $opt_summary_log;

    $the_summary_title = $opt_summary_title;

    $the_logdir_url = $opt_logdir_url;

    $the_rpm_url = $opt_rpm_url;

    $the_srpm_url = $opt_srpm_url;

    $the_source_dirs = $opt_sourcedirs;

    $the_tarball_dir = $opt_tarballdir;

    $the_patch_dir = $opt_patchdir;

    $the_sys_rpm_dir = $opt_rpmdir;

    $the_good_build_dir = $opt_good_build_dir;

    $the_good_rpms_copy_dir = $opt_good_rpms_copy_dir;

    $check_deps = $opt_deps;

    $live_summary = $opt_live_summary;

    $is_nightly = $opt_nightly;

    $the_nightly_date_format = $opt_date;

    @the_source_dirlist = split /:/, $the_source_dirs;

}

sub usage (;$) {

    my $retval = shift;

    if (not defined ($retval)) {

	$retval = 0;

    }

    print << "EOF";

build-gnome2 [options] [command] specs...

Options:

    -v|--verbose:    

                  Increase verbosity: the more -v's the more diag messages

    -q|--quiet:

                  Silent operation.

    --specdir=dir, --spec=dir:

                  Use dir as the default directory for spec files.

                  Default: $default_spec_dir

    --tarballdir=dir, --tardir=dir, --tar=dir:

                  Search for source tarballs in dir.

                  Default: $default_tarball_dir

    --sourcedir=dir, --srcdir=dir, --src=dir:

                  Location of the additional sources referenced in the spec

                  files. Default: $default_spec_dir

    --patchdir=dir, --patch=dir:

                  Look for the patches referenced in the spec files in dir.

                  Default: $default_patch_dir

    --rpmdir=dir --rpm=dir:

                  Use dir as the rpm base directory (where the SPECS,

                  SOURCES, RPMS, SRPMS, BUILD directories are found).

                  Default: $default_sys_rpm_dir

    --logdir=dir, --log=dir:

                  Write build logs to dir. Default: $default_log_dir

    --nodeps, --deps:

                  Ignore/verify dependencies before building a component.

                  Default: --deps

    --target=arch

		  If used, the same option will be passed to rpm when

		  building the package(s)

    --halt-on-errors:

                  Halt on the first build error, do not attempt to continue.

    --full-path:

                  Print the full path to the rpm when running install-order.

    --nightly, --nonightly:

                  Suffix/Don't suffix the rpm Release with the current date.

                  Default: --nonightly;

    --date-format=format, --date=format:

                  Use "date +format" to generate the date suffix for

                  the nightly builds. Default: $default_nightly_date_format

Commands:

    build          Build the specs specified on the command line

    build-order    Print the build order of the specs specified on the

	           command line.

    install-order  Print the rpms in the order they should be installed

    uninstall-pkgs Remove all rpms defined in the spec files specified

		   on the command line. (runs rpm --erase --nodeps)

specs...

    List of spec files to build. Either full path names or names of spec

    files in the default spec directory (with or without the .spec suffix).

EOF

    exit $retval;

}

# --------- print reports --------------------------------------------------

# plain text report on stdout and

# html report if summary log file name

# was specified on the command line

sub print_status {

    print_status_text ();

    print_status_html ();

}

sub print_live_status {

    if ($live_summary) {

	print_status_html ();

    }

}

sub print_status_text {

    my $spec_name;

    print "\nSummary:\n\n";

    printf "%20s | %10s | %s\n", "package", "status", "details";

    print "---------------------+------------+------------------------------------------\n";

    for (my $i = 0; $i <= $#specs_to_build; $i++) {

	$spec_name=$specs_to_build[$i]->{name};

	printf "%20s | %10s | %s\n", $spec_name, $build_status[$i], 

		$status_details[$i];

    }

}

sub print_status_html {

    my $spec_name;

    if (not defined ($the_summary_log)) {

	return;

    }

    if (! open SUM_LOG, ">$the_summary_log") {

	msg_warning (0, "Failed to open file $the_summary_log for writing");

	return;